Rieccomi ancora una volta per chiedere aiuto.




Uploaded with ImageShack.us"/>

Come da immagine, vorrei eliminare, se possibile, alcune voci nel menù che si apre clik destro su lettere di colonna o numero di riga in excel 2003.

Grazie della tua cortese collaborazione.

salve
ti posto alcune macro per operare sulle barre degli strumenti:

Per individuare il nome delle barre degli strumenti usa questa macro:

Sub ListaStrumenti()
Dim N As Long
With Application.CommandBars
For N = 1 To .Count
Cells(N, 1).Value = .Item(N).Name
Next N
End With
End Sub


Nella Lista che verrà generata, troverai la barra degli strumenti "Column" e la barra degli strumenti "Row"
(menù contestuali delle colonne e delle righe)

con queste due macro che seguono, troverai i comandi pertinenti alla barra delle colonne:

Sub ListaComandiColumn()
Dim ctrl As CommandBarControl
riga = 1
For Each ctrl In Application.CommandBars("Column").Controls
Cells(riga, 2).Value = ctrl.Caption
riga = riga + 1
Next
End Sub

e alla barra delle righe:

Sub ListaComandiCbarRow()
Dim ctrl As CommandBarControl
riga = 1
For Each ctrl In Application.CommandBars("Row").Controls
Cells(riga, 3).Value = ctrl.Caption
riga = riga + 1
Next
End Sub


ora ipotizzando di voler disabilitare il comando "inserisci" delle colonne userai questa macro

Sub disabilitaCbarColumn()
Dim ctrl As CommandBarControl
For Each ctrl In Application.CommandBars("Column").Controls
If ctrl.Caption = "&Inserisci" Then ctrl.Enabled = False
Next
End Sub

per disabilitare il comando "nascondi" delle righe userai questa:

Sub disabilitaCbarRow()
Dim ctrl As CommandBarControl
For Each ctrl In Application.CommandBars("Row").Controls
If ctrl.Caption = "&Nascondi" Then ctrl.Enabled = False
Next
End Sub


NB. ricordati se ne fai uso su pc non tuoi di riabilitare i comandi con l'istruzione True alla chiusura del file

saluti
Giap

---